Удалить определенные поля из строки

Следующий скрипт будет (почти) делать, как вы просите.

#!/usr/bin/env perl

use strict;
use warnings;

while(<DATA>) {
    s!^(Modified\s+folders:\s+)((?:[^/]+/){1,3}).*?$!$1$2!;
    print;
}

__DATA__
Modified folders: html/project1/old/dev/vendor/symfony/yaml/Tests/bla.yml
Modified folders: html/port5/.DS_Store
Modified folders: html/trap/dev8/.DS_Store
Modified folders: html/bla3/test/appl/.DS_Store
Modified folders: html/bla4/pro1/app/bla/Api2.php
Modified folders: html/bla10/dev/appl/language/.DS_Store
Modified folders: html/bla11/dev/appl/language/abc.txt

Он читает каждую входную строку, выбирает некоторые значения из нее (мои средства регулярного выражения), заменяет строку выбранными значениями и, наконец, печатает теперь измененную строку (в STDOUT).

Выход

Modified folders: html/project1/old/
Modified folders: html/port5/
Modified folders: html/trap/dev8/
Modified folders: html/bla3/test/
Modified folders: html/bla4/pro1/
Modified folders: html/bla10/dev/
Modified folders: html/bla11/dev/

Если мы напишем регулярное выражение в одну строку:

s!^(Modified\s+folders:\s+)((?:[^/]+/){1,3}).*?$!$1$2!;

тогда это выглядит немного страшно, но на самом деле все довольно просто. Основной оператор - оператор замещенияs/// из Perl.

s/foo/bar/;

заменит каждый случай foo с bar, s позволяет нам изменить разделитель из / к чему-то другому. Я использовал ! здесь, чтобы мы могли также написать

s!foo!bar!;

! не значит not это просто произвольный символ здесь. sLfooLbarL; будет работать так же. Мы делаем это потому, что если мы используем стандарт / нам нужно будет избежать / в пределах параметров (который затем известен как синтаксис зубочистки). Считайте, что мы хотим заменить путь /old/path с /new/path, Теперь сравните:

s/\/old\/path/\/new\/path/; # escaping of / needed
s!/old/path!/new/path!;     # no escaping of / needed (but of ! if we had one in the text)

Мы также можем применить x модификатор к s///, Это позволяет использовать произвольный пробел (даже новые строки и комментарии) в шаблоне (левая сторона) для улучшения читабельности. Теперь цикл можно записать так:

while(<DATA>) {
    s!^                         # match beginning of line
      (Modified\s+folders:\s+)  # the word "Modified", followed by 1 ore more 
                                # whitespace \s+,
                                # the literal "folders:", also followed by 1 or 
                                # more whitespace.
                                # We capture that match in $1 (that's why we have 
                                # parens around it).
      (                         # begin of 2nd capture group (in $2)
        (?:                     #   begin a group that is NOT captured (because of the "?:"
         [^/]+/                 #   one or more characters that are not a slash followed by a slash
        )                       #   end of group
        {1,3}                   #   this group should appear one to three times
      )                         # close capture group $2, i.e. remember the 1-3x slash thing
      .*?$                      # followed by arbitrary characters up to the end of line
     !$1$2!x;                   # Replace the line with the two found captures $1 and $2, i.e.
                                # with the text "Modified folders:" and the 1-3x slash thing.
    print;
}

Полный "скрипт" также может быть записан в виде одной строки:

perl -pe 's!^(Modified\s+folders:\s+)((?:[^/]+/){1,3}).*?$!$1$2!x;' file

Обновить

Я только что понял, что Modified folders: Строка также может рассматриваться как компонент пути. Таким образом, шаблон может быть упрощен до

perl -pe 's!^((?:[^/]+/){1,3}).*?$!$1!;' file

grep -oP '^.*?(/.*?){0,2}(?=/)'

краткое объяснение использованного темного регулярного выражения:

• ^... я начало строки
• .*? последовательность символов (но только необходимое количество), чтобы соответствовать предварительному пути
• /.*?){0,2} 0, 1 или 2 каталога
• (?=/) смотреть вперед выражение - с последующим / это не входит